TEMPLATE = lib
CONFIG   += c++11
CONFIG   -= qt
CONFIG   += staticlib

QMAKE_CXXFLAGS_DEBUG += -Wno-unused-parameter -Wno-unused-but-set-variable
QMAKE_CXXFLAGS += -Wstrict-aliasing=0 -D_REST -D_LIBBUILD
QMAKE_CFLAGS += -D_REST -D_LIBBUILD
# QMAKE_LIBDIR += $$OUT_PWD/../common $$[QT_SYSROOT]/usr/lib/gfa
# QMAKE_LIBS += -lm -lstdc++ -lgfaipc -lulfius -ljansson -pthread -lpthread -lorcania -lcurl -lssl -lcrypto -l:libcommon.a
QMAKE_RPATHDIR += /usr/lib/gfa

_LIB_PATH = $$[QT_SYSROOT]/usr/lib/gfa/svc/
_INC_PATH = $$[QT_SYSROOT]/usr/include/gfa/svc/rest/

CONFIG(debug, debug|release) {
    QMAKE_CXXFLAGS -= -Os
    QMAKE_CFLAGS -= -Os
    QMAKE_CXXFLAGS += -D_DEBUG
    QMAKE_CFLAGS += -D_DEBUG
	TARGET = restd
	QMAKE_CLEAN += librestd.a
}

CONFIG(release, debug|release) {
    QMAKE_CXXFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
    QMAKE_CFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
	TARGET = rest
	QMAKE_CLEAN += librest.a
}

linux-buildroot-g++ {
    QMAKE_CXXFLAGS += -D_TARGET_BUILD
    QMAKE_CFLAGS += -D_TARGET_BUILD
    QMAKE_CXXFLAGS += -DSITARA_BUILD
    QMAKE_CFLAGS += -DSITARA_BUILD
}

INCLUDEPATH += ../ ../common $$(GEBGFADEV)

SOURCES += restvartbl.cpp \
    restvar.cpp \
    reststrvar.cpp \
    restbitvar.cpp \
    callback.cpp \
    helpers.cpp

HEADERS += main.h \
    restvar.h \
    helpers.h \
    defines.h \
    callback.h

includes.path = $$_INC_PATH
includes.extra += -$(INSTALL_FILE) $$PWD/main.h $(INSTALL_ROOT)$$includes.path
includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/restvar.h $(INSTALL_ROOT)$$includes.path
includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/helpers.h $(INSTALL_ROOT)$$includes.path
includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/defines.h $(INSTALL_ROOT)$$includes.path
includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/callback.h $(INSTALL_ROOT)$$includes.path
includes.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/main.h
includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/restvar.h
includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/helpers.h
includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/defines.h
includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/callback.h
INSTALLS += includes

library.path = $$_LIB_PATH
library.extra += -$(INSTALL_FILE) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET)
library.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET)
INSTALLS += library